1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
|
#lang racket
(provide nutrient-measurement
nutrient-measurement?
nutrient-measurement-id
(rename-out [nutrient-measurement-measurement-date nutrient-measurement-date]
[nutrient-measurement-nutrient-values nutrient-measurement-values])
(contract-out
[create-nutrient-measurement! (-> string? nutrient-value-hash/c nutrient-measurement?)]
[get-nutrient-measurements (-> (listof nutrient-measurement?))]
[get-nutrient-measurement
(->* ()
(#:id exact-nonnegative-integer? #:date string?)
(or/c nutrient-measurement? #f))]
[get-nutrient-measurement-values (-> nutrient-measurement-or-id/c nutrient-value-hash/c)]
[get-nutrient-measurement-value
(-> nutrient-measurement-or-id/c nutrient? maybe-nutrient-value?)]
[get-latest-nutrient-measurement-value (-> nutrient? maybe-nutrient-value?)]
[get-latest-nutrient-measurement-hash (-> nutrient-value-hash/c)]
[delete-nutrient-measurement! (-> nutrient-measurement-or-id/c void?)]))
(require racket/contract
db
sql
"../db/conn.rkt"
"nutrient.rkt")
(struct nutrient-measurement (id measurement-date nutrient-values)
#:transparent
#:property prop:custom-write
(λ (v out _)
(fprintf out
"Measurement #~a on ~a\n"
(nutrient-measurement-id v)
(nutrient-measurement-measurement-date v))
(for ([(n v) (in-hash (nutrient-measurement-nutrient-values v))])
(fprintf out
"~a ~a\n"
(~a (nutrient-canonical-name n) #:min-width 14)
(~a v #:max-width 6 #:align 'right)))))
(define nutrient-measurement-id? exact-nonnegative-integer?)
(define nutrient-measurement-or-id/c (or/c nutrient-measurement? nutrient-measurement-id?))
(define (->nm-id nm-or-id)
(match nm-or-id
[(? nutrient-measurement-id? id) id]
[(nutrient-measurement id _ _) id]))
;; CREATE
(define (create-nutrient-measurement! measurement-date nutrient-values)
(or
(get-nutrient-measurement #:date measurement-date)
(with-tx
(query-exec (current-conn) (insert #:into nutrient_measurements #:set [measurement_date ,measurement-date]))
(define nm-id
(query-value (current-conn)
(select id #:from nutrient_measurements #:where (= measurement_date ,measurement-date))))
(query-exec (current-conn)
(insert #:into nutrient_value_sets #:set [nutrient_measurement_id ,nm-id]))
(define nvs-id
(query-value (current-conn)
(select id #:from nutrient_value_sets #:where (= nutrient_measurement_id ,nm-id))))
(for ([(n v) (in-hash nutrient-values)])
(query-exec (current-conn)
(insert #:into nutrient_values
#:set [value_set_id ,nvs-id]
[nutrient_id ,(nutrient-id n)]
[value_ppm ,v])))
(get-nutrient-measurement #:date measurement-date))))
;; READ
(define joined
(table-expr-qq (inner-join (inner-join (inner-join (as nutrient_measurements nm)
(as nutrient_value_sets nvs)
#:on (= nvs.nutrient_measurement_id nm.id))
(as nutrient_values nv)
#:on (= nv.value_set_id nvs.id))
(as nutrients n)
#:on (= n.id nv.nutrient_id))))
(define (grouped-row->nutrient-measurement row)
(match-define (vector nm-id measurement-date residuals) row)
(nutrient-measurement nm-id measurement-date (residuals->nutrient-value-hash residuals)))
(define (get-nutrient-measurements)
(define grouped-rows
(query-rows (current-conn)
(select nm.id
nm.measurement_date
n.id
n.canonical_name
n.french_name
n.formula
nv.value_ppm
#:from (TableExpr:AST ,joined)
#:order-by nm.measurement_date
#:desc)
#:group '#(0 1)))
(for/list ([row grouped-rows])
(grouped-row->nutrient-measurement row)))
(define (get-nutrient-measurement #:id [nm-id #f] #:date [measurement-date #f])
(define where
(cond
[(and nm-id measurement-date)
(scalar-expr-qq (and (= nm.id ,nm-id) (= nm.measurement_date ,measurement-date)))]
[nm-id (scalar-expr-qq (= nm.id ,nm-id))]
[measurement-date (scalar-expr-qq (= nm.measurement_date ,measurement-date))]
[else (error 'get-nutrient-measurement "either #:id or #:date must be provided")]))
(define grouped-rows
(query-rows (current-conn)
(select nm.id
nm.measurement_date
n.id
n.canonical_name
n.french_name
n.formula
nv.value_ppm
#:from (TableExpr:AST ,joined)
#:where (ScalarExpr:AST ,where)
#:order-by nm.measurement_date
#:desc)
#:group '#(0 1)))
(match grouped-rows
['() #f]
[(list row) (grouped-row->nutrient-measurement row)]
[many (error 'get-nutrient-measurement "expected 1 nutrient measurement, got ~a" (length many))]))
(define (get-nutrient-measurement-values nm-or-id)
(for/hash ([(nutrient-id canonical-name french-name formula value_ppm)
(in-query (current-conn)
(select n.id
n.canonical_name
n.french_name
n.formula
nv.value_ppm
#:from (TableExpr:AST ,joined)
#:where (= nm.id ,(->nm-id nm-or-id))))])
(values (nutrient nutrient-id canonical-name french-name formula) value_ppm)))
(define (get-nutrient-measurement-value nm-or-id nutrient)
(query-maybe-value (current-conn)
(select value_ppm
#:from (TableExpr:AST ,joined)
#:where (and (= nm.id ,(->nm-id nm-or-id))
(= nv.nutrient_id ,(nutrient-id nutrient))))))
(define (get-latest-nutrient-measurement-value nutrient)
(query-maybe-value (current-conn)
(select value_ppm
#:from (TableExpr:AST ,joined)
#:where (= nv.nutrient_id ,(nutrient-id nutrient))
#:order-by nm.measurement_date
#:desc
#:limit 1)))
(define (get-latest-nutrient-measurement-hash)
(define grouped-rows
(query-rows (current-conn)
(select n.id
n.canonical_name
n.french_name
n.formula
nm.measurement_date
nv.value_ppm
#:from (TableExpr:AST ,joined)
#:order-by nm.measurement_date
#:desc)
#:group '(#(0 1 2 3))))
(for/hash ([row grouped-rows])
(match-define (vector n-id n-canonical-name n-french-name n-formula residual-rows) row)
;; residual-rows is a non-empty list of vectors: #(measurement_date value_ppm)
(match-define (vector _ value-ppm) (first residual-rows))
(values (nutrient n-id n-canonical-name n-french-name n-formula) value-ppm)))
;; UPDATE
;; DELETE
(define (delete-nutrient-measurement! nm-or-id)
(query-exec (current-conn)
(delete #:from nutrient_measurements #:where (= id ,(->nm-id nm-or-id)))))
(module+ test
(require rackunit
rackunit/text-ui
"../db/conn.rkt"
"../db/migrations.rkt"
"../models/nutrient.rkt")
(define measurement-date "2025-09-01")
(run-tests
(test-suite "Nutrient measurement model"
#:before (λ ()
(connect! #:path 'memory)
;; (connect! #:path "test.sqlite3")
(migrate-all!)
(create-nutrient! "Nitrogen" "" "N")
(create-nutrient! "Phosphorus" "" "P")
(create-nutrient! "Potassium" "" "K"))
#:after (λ () (disconnect!))
(test-case "Create measurement with date and values"
(define nitrogen (get-nutrient #:name "Nitrogen"))
(define phosphorus (get-nutrient #:name "Phosphorus"))
(create-nutrient-measurement! measurement-date (hash nitrogen 12.3 phosphorus 4.5))
(check-equal? (length (get-nutrient-measurements)) 1)
(define nm (get-nutrient-measurement #:date measurement-date))
(check-true (nutrient-measurement? nm))
(check-equal? (nutrient-measurement-measurement-date nm) measurement-date))
(test-case "Check all measurement values"
(define nitrogen (get-nutrient #:name "Nitrogen"))
(define phosphorus (get-nutrient #:name "Phosphorus"))
(define nm (get-nutrient-measurement #:date measurement-date))
(check-equal? (get-nutrient-measurement-value nm nitrogen) 12.3)
(check-equal? (get-nutrient-measurement-value nm phosphorus) 4.5)
(define nmv (nutrient-measurement-nutrient-values nm))
(check-equal?
(get-nutrient-measurement-values nm)
nmv
"return value of get-nutrient-measurement-values ≠ nutrient-measurement-values struct accessor")
(check-equal? (hash-count nmv) 2)
(check-equal? (hash-ref nmv nitrogen) 12.3)
(check-equal? (hash-ref nmv phosphorus) 4.5))
(test-case "Retrieve latest measurement values"
(define nitrogen (get-nutrient #:name "Nitrogen"))
(define phosphorus (get-nutrient #:name "Phosphorus"))
(define second-measurement-date "2025-09-02")
(create-nutrient-measurement! second-measurement-date (hash nitrogen 6.7 phosphorus 8.9))
(check-equal? (get-latest-nutrient-measurement-value nitrogen) 6.7)
(check-equal? (get-latest-nutrient-measurement-value phosphorus) 8.9))
(test-case "Delete measurement and cascade to measurement values"
(define nm (get-nutrient-measurement #:date measurement-date))
(delete-nutrient-measurement! nm)
(check-false (get-nutrient-measurement #:id (nutrient-measurement-id nm)))
(check-equal? (length (get-nutrient-measurements))
1
"wrong number of nutrient measurements were deleted")
(check-true (hash-empty? (get-nutrient-measurement-values nm)))))))
|
