Move tests to concerned modules.

1 files changed, 64 insertions, 0 deletions

diff --git a/models/nutrient-measurement.rkt b/models/nutrient-measurement.rkt
index 5b5f93d..913e402 100644
--- a/models/nutrient-measurement.rkt
+++ b/models/nutrient-measurement.rkt
@@ -174,3 +174,67 @@
 (define (delete-nutrient-measurement! nutrient-measurement)
   (define id (nutrient-measurement-id nutrient-measurement))
   (query-exec (current-conn) (delete #:from nutrient_measurements #:where (= id ,id))))
+
+(module+ test
+  (require rackunit
+           rackunit/text-ui
+           "../db/conn.rkt"
+           "../db/migrations.rkt"
+           "../models/nutrient.rkt")
+
+  (define measurement-date "2025-09-01")
+
+  (run-tests
+   (test-suite "Nutrient measurement model"
+     #:before (λ ()
+                (connect! #:path 'memory)
+                ;; (connect! #:path "test.sqlite3")
+                (migrate-all!)
+                (create-nutrient! "Nitrogen" "" "N")
+                (create-nutrient! "Phosphorus" "" "P")
+                (create-nutrient! "Potassium" "" "K"))
+     #:after (λ () (disconnect!))
+
+     (test-case "Create measurement with date and values"
+       (define nitrogen (get-nutrient #:name "Nitrogen"))
+       (define phosphorus (get-nutrient #:name "Phosphorus"))
+       (create-nutrient-measurement! measurement-date (hash nitrogen 12.3 phosphorus 4.5))
+       (check-equal? (length (get-nutrient-measurements)) 1)
+       (define nm (get-nutrient-measurement #:measured-on measurement-date))
+       (check-true (nutrient-measurement? nm))
+       (check-equal? (nutrient-measurement-measured-on nm) measurement-date))
+
+     (test-case "Check all measurement values"
+       (define nitrogen (get-nutrient #:name "Nitrogen"))
+       (define phosphorus (get-nutrient #:name "Phosphorus"))
+
+       (define nm (get-nutrient-measurement #:measured-on measurement-date))
+       (check-equal? (get-nutrient-measurement-value nm nitrogen) 12.3)
+       (check-equal? (get-nutrient-measurement-value nm phosphorus) 4.5)
+
+       (define nmv (nutrient-measurement-nutrient-values nm))
+       (check-equal?
+        (get-nutrient-measurement-values nm)
+        nmv
+        "return value of get-nutrient-measurement-values ≠ nutrient-measurement-values struct accessor")
+       (check-equal? (hash-count nmv) 2)
+       (check-equal? (hash-ref nmv nitrogen) 12.3)
+       (check-equal? (hash-ref nmv phosphorus) 4.5))
+
+     (test-case "Retrieve latest measurement values"
+       (define nitrogen (get-nutrient #:name "Nitrogen"))
+       (define phosphorus (get-nutrient #:name "Phosphorus"))
+       (define second-measurement-date "2025-09-02")
+       (create-nutrient-measurement! second-measurement-date (hash nitrogen 6.7 phosphorus 8.9))
+
+       (check-equal? (get-latest-nutrient-measurement-value nitrogen) 6.7)
+       (check-equal? (get-latest-nutrient-measurement-value phosphorus) 8.9))
+
+     (test-case "Delete measurement and cascade to measurement values"
+       (define nm (get-nutrient-measurement #:measured-on measurement-date))
+       (delete-nutrient-measurement! nm)
+       (check-false (get-nutrient-measurement #:id (nutrient-measurement-id nm)))
+       (check-equal? (length (get-nutrient-measurements))
+                     1
+                     "wrong number of nutrient measurements were deleted")
+       (check-true (hash-empty? (get-nutrient-measurement-values nm)))))))