Class {
	#name : 'MFTRootComponent',
	#superclass : 'WAComponent',
	#instVars : [
		'main'
	],
	#category : 'MyFitnessTracker-Web-Components',
	#package : 'MyFitnessTracker-Web',
	#tag : 'Components'
}

{ #category : 'testing' }
MFTRootComponent class >> canBeRoot [

	^ true
]

{ #category : 'class initialization' }
MFTRootComponent class >> initialize [

	| application |
	application := WAAdmin register: self asApplicationAt: 'mft'.
	application preferenceAt: #sessionClass put: MFTSession.
	^ application
]

{ #category : 'hooks' }
MFTRootComponent >> children [

	^ { main }
]

{ #category : 'initialization' }
MFTRootComponent >> initialize [

	super initialize.
	main := MFTScreenComponent new
]

{ #category : 'rendering' }
MFTRootComponent >> renderContentOn: html [

	html render: main
]

{ #category : 'updating' }
MFTRootComponent >> updateRoot: aRoot [

	super updateRoot: aRoot.
	aRoot beHtml5.
	aRoot meta
		name: 'viewport';
		content: 'width=device-width, initial-scale=1'.
	aRoot title: 'MFT ' , main activePage title.
	aRoot link
		beShortcutIcon;
		url: MFTFileLibrary / #faviconPng.
	aRoot stylesheet url:
		'https://cdn.jsdelivr.net/npm/@picocss/pico@2/css/pico.min.css'.
	aRoot stylesheet url: MFTFileLibrary / #defaultCss.
	aRoot stylesheet url: 'https://rsms.me/inter/inter.css'
]