"
I represent an equipment that can be used for a MFTExercise.
"
Class {
	#name : 'MFTEquipment',
	#superclass : 'MFTObject',
	#instVars : [
		'englishName'
	],
	#category : 'MyFitnessTracker-Core-Base',
	#package : 'MyFitnessTracker-Core',
	#tag : 'Base'
}

{ #category : 'freeweights' }
MFTEquipment class >> barbell [

	^ self newWithEnglishName
]

{ #category : 'machines' }
MFTEquipment class >> cable [

	^ self newWithEnglishName
]

{ #category : 'freeweights' }
MFTEquipment class >> dumbbell [

	^ self newWithEnglishName
]

{ #category : 'freeweights' }
MFTEquipment class >> ezBar [

	^ self new
		  englishName: 'EZ bar';
		  yourself
]

{ #category : 'machines' }
MFTEquipment class >> legExtensionMachine [

	^ self newWithEnglishName
]

{ #category : 'machines' }
MFTEquipment class >> legPressMachine [

	^ self newWithEnglishName
]

{ #category : 'as yet unclassified' }
MFTEquipment class >> newWithEnglishName [
	"I return a MFTEquipment instance for which englishName is set to the calling method selector, as a space-separated string."

	| equipmentNameFromSender |
	equipmentNameFromSender := (thisContext sender selector
		                            splitCamelCase collect: #asLowercase)
		                           joinUsing: Character space.
	^ self new englishName: equipmentNameFromSender
]

{ #category : 'machines' }
MFTEquipment class >> pecDeck [

	^ self newWithEnglishName
]

{ #category : 'machines' }
MFTEquipment class >> seatedLegCurlMachine [

	^ self newWithEnglishName
]

{ #category : 'comparing' }
MFTEquipment >> = anObject [
	"Answer whether the receiver and anObject represent the same object."

	self == anObject ifTrue: [ ^ true ].
	self class = anObject class ifFalse: [ ^ false ].
	^ englishName = anObject canonicalName
]

{ #category : 'initialization' }
MFTEquipment >> canonicalName [

	^ englishName
]

{ #category : 'accessing' }
MFTEquipment >> englishName [

	^ englishName
]

{ #category : 'accessing' }
MFTEquipment >> englishName: aString [

	englishName := aString
]

{ #category : 'comparing' }
MFTEquipment >> hash [
	"Answer an integer value that is related to the identity of the receiver."

	^ englishName hash
]